Move optimized memcpy and friends and strlen to firmware/asm,

using the new automatic-asm-picking infrastructure.

5 files changed, 0 insertions, 1721 deletions

diff --git a/firmware/target/coldfire/memcpy-coldfire.S b/firmware/target/coldfire/memcpy-coldfire.S
deleted file mode 100644
index 9762e31e02..0000000000
--- a/firmware/target/coldfire/memcpy-coldfire.S
+++ /dev/null
@@ -1,682 +0,0 @@
-/***************************************************************************
- *             __________               __   ___.
- *   Open      \______   \ ____   ____ |  | _\_ |__   _______  ___
- *   Source     |       _//  _ \_/ ___\|  |/ /| __ \ /  _ \  \/  /
- *   Jukebox    |    |   (  <_> )  \___|    < | \_\ (  <_> > <  <
- *   Firmware   |____|_  /\____/ \___  >__|_ \|___  /\____/__/\_ \
- *                     \/            \/     \/    \/            \/
- * $Id$
- *
- * Copyright (C) 2004-2005 by Jens Arnold
- *
- * This program is free software; you can redistribute it and/or
- * modify it under the terms of the GNU General Public License
- * as published by the Free Software Foundation; either version 2
- * of the License, or (at your option) any later version.
- *
- * This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
- * KIND, either express or implied.
- *
- ****************************************************************************/
-#include "config.h"
-
-    .section    .icode,"ax",@progbits
-
-#define FULLSPEED /* use burst writing for word aligned destinations */
-    .align  2
-    .global memcpy
-    .global __memcpy_fwd_entry
-    .type   memcpy,@function
-
-/* Copies <length> bytes of data in memory from <source> to <dest>
- * This version is optimized for speed
- *
- * arguments:
- *  (4,%sp)  - destination address
- *  (8,%sp)  - source address
- *  (12,%sp) - length
- *
- * return value:
- *  %d0 - destination address (like ANSI version)
- *
- * register usage:
- *  %a0 - current source address
- *  %a1 - current dest address
- *  %a2 - source end address (in line-copy loops)
- *  %d0 - data / scratch
- *  %d1 - source end address (byte and longword copy) / data / scratch
- *  %d2 - data / scratch
- *  %d3..%d7 - data
- *
- * For maximum speed this routine reads and writes whole lines using burst
- * move (movem.l) where possible. For byte aligned destinations (long+1 and
- * long+3) it writes longwords only. Same goes for word aligned destinations
- * if FULLSPEED is undefined.
- */
-memcpy:
-    move.l  (4,%sp),%a1     /* Destination */
-    move.l  (8,%sp),%a0     /* Source */
-    move.l  (12,%sp),%d1    /* Length */
-
-__memcpy_fwd_entry:
-    add.l   %a0,%d1         /* %d1 = source end */
-
-    move.l  %a0,%d0
-    addq.l  #7,%d0
-    and.l   #0xFFFFFFFC,%d0 /* %d0 = first source long bound + 4 */
-    cmp.l   %d0,%d1         /* at least one aligned longword to copy? */
-    blo.w   .bytes2_start   /* no, jump directly to trailing byte loop */
-    
-    subq.l  #4,%d0          /* %d0 = first source long bound */
-    cmp.l   %a0,%d0         /* any bytes to copy? */
-    jls     .bytes1_end     /* no: skip byte loop */
-
-    /* leading byte loop: copies 0..3 bytes */
-.bytes1_loop:
-    move.b  (%a0)+,(%a1)+   /* copy byte */
-    cmp.l   %a0,%d0         /* runs %a0 up to first long bound */
-    jhi     .bytes1_loop
-
-.bytes1_end:
-    moveq.l #31,%d0
-    add.l   %a0,%d0
-    and.l   #0xFFFFFFF0,%d0 /* %d0 = first source line bound + 16 */
-    cmp.l   %d0,%d1         /* at least one aligned line to copy? */
-    blo.w   .long_start     /* no: jump to longword copy loop */
-    
-    lea.l   (-28,%sp),%sp   /* free up some registers */
-    movem.l %d2-%d7/%a2,(%sp)
-
-    moveq.l #16,%d2
-    sub.l   %d2,%d0         /* %d0 = first source line bound */
-    move.l  %d1,%a2         /* %a2 = end address */
-    lea.l   (-15,%a2),%a2   /* adjust end address for loops doing 16 bytes/ pass */
-    move.l  %a1,%d1
-    moveq.l #3,%d2          /* mask */
-    and.l   %d2,%d1
-    jmp.l   (2,%pc,%d1.l*4) /* switch (dest_addr & 3) */
-    bra.w   .lines_do0_start
-    bra.w   .lines_do1_start
-    bra.w   .lines_do2_start
- /* bra.w   .lines_do3_start   implicit */
-
-    /* byte aligned destination (long + 3): use line burst reads in main loop */
-.lines_do3_start:
-    moveq.l #24,%d1         /* shift count for shifting by 3 bytes */
-    cmp.l   %a0,%d0         /* any leading longwords? */
-    jhi     .lines_do3_head_start  /* yes: leading longword copy */
-
-    movem.l (%a0),%d4-%d7   /* load first line */
-    lea.l   (16,%a0),%a0
-    move.l  %d4,%d2
-    lsr.l   %d1,%d2         /* get high byte of first longword */
-    move.b  %d2,(%a1)+      /* store byte */
-    jra     .lines_do3_entry       /* jump into main loop */
-    
-.lines_do3_head_start:
-    move.l  (%a0)+,%d7      /* load first longword */
-    move.l  %d7,%d2
-    lsr.l   %d1,%d2         /* get high byte */
-    move.b  %d2,(%a1)+      /* store byte */
-    jra     .lines_do3_head_entry  /* jump into leading longword loop */
-
-.lines_do3_head_loop:
-    move.l  %d7,%d6         /* move old longword away */
-    move.l  (%a0)+,%d7      /* load new longword */
-    move.l  %d7,%d2
-    lsr.l   %d1,%d2         /* get high byte */
-    or.l    %d2,%d6         /* combine with old lower 3 bytes */
-    move.l  %d6,(%a1)+      /* store longword */
-.lines_do3_head_entry:
-    lsl.l   #8,%d7          /* shift up lower 3 bytes */
-    cmp.l   %a0,%d0         /* runs %a0 up to first line bound */
-    jhi     .lines_do3_head_loop
-
-.lines_do3_loop:
-    move.l  %d7,%d3         /* move last longword of old line away */
-    movem.l (%a0),%d4-%d7   /* load new line */
-    lea.l   (16,%a0),%a0
-    move.l  %d4,%d2
-    lsr.l   %d1,%d2         /* get high byte of 1st longword */
-    or.l    %d2,%d3         /* combine with old lower 3 bytes */
-    move.l  %d3,(%a1)+      /* store longword */
-.lines_do3_entry:
-    lsl.l   #8,%d4          /* shift up lower 3 bytes */
-    move.l  %d5,%d2
-    lsr.l   %d1,%d2         /* get high byte of 2nd longword */
-    or.l    %d2,%d4         /* combine with 1st lower 3 bytes */
-    move.l  %d4,(%a1)+      /* store longword */
-    lsl.l   #8,%d5          /* shift up lower 3 bytes */
-    move.l  %d6,%d2
-    lsr.l   %d1,%d2         /* get high byte of 3rd longword */
-    or.l    %d2,%d5         /* combine with 2nd lower 3 bytes */
-    move.l  %d5,(%a1)+      /* store longword */
-    lsl.l   #8,%d6          /* shift up lower 3 bytes */
-    move.l  %d7,%d2
-    lsr.l   %d1,%d2         /* get high byte of 4th longword */
-    or.l    %d2,%d6         /* combine with 3rd lower 3 bytes */
-    move.l  %d6,(%a1)+      /* store longword */
-    lsl.l   #8,%d7          /* shift up lower 3 bytes */
-    cmp.l   %a0,%a2         /* runs %a0 up to last line bound */
-    jhi     .lines_do3_loop
-
-    lea.l   (12,%a2),%a2    /* readjust end address for doing longwords */
-    cmp.l   %a0,%a2         /* any trailing longwords? */
-    jls     .lines_do3_tail_end    /* no: just store last lower 3 bytes */
-
-.lines_do3_tail_loop:
-    move.l  %d7,%d6         /* move old longword away */
-    move.l  (%a0)+,%d7      /* load new longword */
-    move.l  %d7,%d2
-    lsr.l   %d1,%d2         /* get high byte */
-    or.l    %d2,%d6         /* combine with old lower 3 bytes */
-    move.l  %d6,(%a1)+      /* store longword */
-    lsl.l   #8,%d7          /* shift up lower 3 bytes */
-    cmp.l   %a0,%a2         /* runs %a0 up to last long bound */
-    jhi     .lines_do3_tail_loop
-
-.lines_do3_tail_end:
-    swap    %d7             /* get high word */
-    move.w  %d7,(%a1)+      /* store word */
-    lsr.l   %d1,%d7         /* get moved-up low byte */
-    move.b  %d7,(%a1)+      /* store byte */
-    jra     .lines_end
-
-    /* byte aligned destination (long + 1): use line burst reads in main loop */
-.lines_do1_start:
-    moveq.l #24,%d1         /* shift count for shifting by 3 bytes */
-    cmp.l   %a0,%d0         /* any leading longwords? */
-    jhi     .lines_do1_head_start  /* yes: leading longword copy */
-
-    movem.l (%a0),%d4-%d7   /* load first line */
-    lea.l   (16,%a0),%a0
-    move.l  %d4,%d2         /* first longword, bytes 3210 */
-    lsr.l   #8,%d2          /* first longword, bytes .321 */
-    swap    %d2             /* first longword, bytes 21.3 */
-    move.b  %d2,(%a1)+      /* store byte */
-    swap    %d2             /* first longword, bytes .321 */
-    move.w  %d2,(%a1)+      /* store word */
-    jra     .lines_do1_entry
-
-.lines_do1_head_start:
-    move.l  (%a0)+,%d7      /* load first longword */
-    move.l  %d7,%d2         /* first longword, bytes 3210 */
-    lsr.l   #8,%d2          /* first longword, bytes .321 */
-    swap    %d2             /* first longword, bytes 21.3 */
-    move.b  %d2,(%a1)+      /* store byte */
-    swap    %d2             /* first longword, bytes .321 */
-    move.w  %d2,(%a1)+      /* store word */
-    jra     .lines_do1_head_entry
-
-.lines_do1_head_loop:
-    move.l  %d7,%d6         /* move old longword away */
-    move.l  (%a0)+,%d7      /* load new longword */
-    move.l  %d7,%d2
-    lsr.l   #8,%d2          /* get upper 3 bytes */
-    or.l    %d2,%d6         /* combine with old low byte */
-    move.l  %d6,(%a1)+      /* store longword */
-.lines_do1_head_entry:
-    lsl.l   %d1,%d7         /* shift up low byte */
-    cmp.l   %a0,%d0         /* runs %a0 up to first line bound */
-    jhi     .lines_do1_head_loop
-
-.lines_do1_loop:
-    move.l  %d7,%d3         /* move last longword of old line away */
-    movem.l (%a0),%d4-%d7   /* load new line */
-    lea.l   (16,%a0),%a0
-    move.l  %d4,%d2
-    lsr.l   #8,%d2          /* get upper 3 bytes of 1st longword */
-    or.l    %d2,%d3         /* combine with low byte of old longword */
-    move.l  %d3,(%a1)+      /* store longword */
-.lines_do1_entry:
-    lsl.l   %d1,%d4         /* shift up low byte */
-    move.l  %d5,%d2
-    lsr.l   #8,%d2          /* get upper 3 bytes of 2nd longword */
-    or.l    %d2,%d4         /* combine with low byte of 1st longword */
-    move.l  %d4,(%a1)+      /* store longword */
-    lsl.l   %d1,%d5         /* shift up low byte */
-    move.l  %d6,%d2
-    lsr.l   #8,%d2          /* get upper 3 bytes of 3rd longword */
-    or.l    %d2,%d5         /* combine with low byte of 2nd longword */
-    move.l  %d5,(%a1)+      /* store longword */
-    lsl.l   %d1,%d6         /* shift up low byte */
-    move.l  %d7,%d2
-    lsr.l   #8,%d2          /* get upper 3 bytes of 4th longword */
-    or.l    %d2,%d6         /* combine with low byte of 4th longword */
-    move.l  %d6,(%a1)+      /* store longword */
-    lsl.l   %d1,%d7         /* shift up low byte */
-    cmp.l   %a0,%a2         /* runs %a0 up to last line bound */
-    jhi     .lines_do1_loop
-    
-    lea.l   (12,%a2),%a2    /* readjust end address for doing longwords */
-    cmp.l   %a0,%a2         /* any trailing longwords? */
-    jls     .lines_do1_tail_end    /* no: just store last low byte */
-    
-.lines_do1_tail_loop:
-    move.l  %d7,%d6         /* move old longword away */
-    move.l  (%a0)+,%d7      /* load new longword */
-    move.l  %d7,%d2
-    lsr.l   #8,%d2          /* get upper 3 bytes */
-    or.l    %d2,%d6         /* combine with old low byte */
-    move.l  %d6,(%a1)+      /* store longword */
-    lsl.l   %d1,%d7         /* shift up low byte */
-    cmp.l   %a0,%a2         /* runs %a0 up to last long bound */
-    jhi     .lines_do1_tail_loop
-
-.lines_do1_tail_end:
-    lsr.l   %d1,%d7         /* get shifted-up low byte */
-    move.b  %d7,(%a1)+      /* store byte */
-    jra     .lines_end
-
-    /* long aligned destination (line + 0/4/8/12): head */
-.lines_do0_head_loop:
-    move.l  (%a0)+,(%a1)+   /* copy longword */
-.lines_do0_start:
-    cmp.l   %a0,%d0         /* runs %a0 up to first line bound */
-    jhi     .lines_do0_head_loop
-
-.lines_do0_head_end:
-    move.l  %a1,%d1
-    lsr.l   #2,%d1
-    moveq.l #3,%d0          /* mask */
-    and.l   %d0,%d1
-    moveq.l #16,%d0         /* address increment for one main loop pass */
-    jmp.l   (2,%pc,%d1.l*2) /* switch ((dest_addr >> 2) & 3) */
-    bra.b   .lines_lo0_start
-    bra.b   .lines_lo4_start
-    bra.b   .lines_lo8_start
- /* bra.b   .lines_lo12_start   implicit */
-
-    /* long aligned destination (line + 12): use line bursts in the loop */
-.lines_lo12_start:
-    movem.l (%a0),%d4-%d7   /* load first line */
-    add.l   %d0,%a0
-    move.l  %d4,(%a1)+      /* store 1st longword */
-    cmp.l   %a0,%a2         /* any full lines? */
-    jls     .lines_lo12_end /* no: skip main loop */
-
-.lines_lo12_loop:
-    move.l  %d5,%d1         /* move last 3 longwords of old line away */
-    move.l  %d6,%d2
-    move.l  %d7,%d3
-    movem.l (%a0),%d4-%d7   /* load new line */
-    add.l   %d0,%a0
-    movem.l %d1-%d4,(%a1)   /* store line (3 old + 1 new longwords) */
-    add.l   %d0,%a1
-    cmp.l   %a0,%a2         /* runs %a0 up to last line bound */
-    jhi     .lines_lo12_loop
-
-    /* long aligned destination (line + 0/4/8/12): tail */
-.lines_lo12_end:
-    move.l  %d5,(%a1)+      /* store 3rd last longword */
-.lines_lo8_end:
-    move.l  %d6,(%a1)+      /* store 2nd last longword */
-.lines_lo4_end:
-    move.l  %d7,(%a1)+      /* store last longword */
-.lines_lo0_end:
-    lea.l   (12,%a2),%a2    /* readjust end address for doing longwords */
-    cmp.l   %a0,%a2         /* any trailing longwords? */
-    jls     .lines_end      /* no: get outta here */
-
-.lines_do0_tail_loop:
-    move.l  (%a0)+,(%a1)+   /* copy longword */
-    cmp.l   %a0,%a2         /* runs %a0 up to last long bound */
-    jhi     .lines_do0_tail_loop
-
-    jra     .lines_end 
-    
-    /* line aligned destination: use line bursts in the loop */
-.lines_lo0_start:
-.lines_lo0_loop:
-    movem.l (%a0),%d4-%d7   /* load line */
-    add.l   %d0,%a0
-    movem.l %d4-%d7,(%a1)   /* store line */
-    add.l   %d0,%a1
-    cmp.l   %a0,%a2         /* runs %a0 up to last line bound */
-    jhi     .lines_lo0_loop
-
-    jra     .lines_lo0_end  /* handle trailing longwords */
-
-    /* long aligned destination (line + 4): use line bursts in the loop */
-.lines_lo4_start:
-    movem.l (%a0),%d4-%d7   /* load first line */
-    add.l   %d0,%a0
-    move.l  %d4,(%a1)+      /* store 1st longword */
-    move.l  %d5,(%a1)+      /* store 2nd longword */
-    move.l  %d6,(%a1)+      /* store 3rd longword */
-    cmp.l   %a0,%a2         /* any full lines? */
-    jls     .lines_lo4_end  /* no: skip main loop */
-
-.lines_lo4_loop:
-    move.l  %d7,%d3         /* move last longword of old line away */
-    movem.l (%a0),%d4-%d7   /* load new line */
-    add.l   %d0,%a0
-    movem.l %d3-%d6,(%a1)   /* store line (1 old + 3 new longwords) */
-    add.l   %d0,%a1
-    cmp.l   %a0,%a2         /* runs %a0 up to last line bound */
-    jhi     .lines_lo4_loop
-
-    jra     .lines_lo4_end  /* handle trailing longwords */
-
-    /* long aligned destination (line + 8): use line bursts in the loop */
-.lines_lo8_start:
-    movem.l (%a0),%d4-%d7   /* load first line */
-    add.l   %d0,%a0
-    move.l  %d4,(%a1)+      /* store 1st longword */
-    move.l  %d5,(%a1)+      /* store 2nd longword */
-    cmp.l   %a0,%a2
-    jls     .lines_lo8_end
-
-.lines_lo8_loop:
-    move.l  %d6,%d2         /* move last 2 longwords of old line away */
-    move.l  %d7,%d3
-    movem.l (%a0),%d4-%d7   /* load new line */
-    add.l   %d0,%a0
-    movem.l %d2-%d5,(%a1)   /* store line (2 old + 2 new longwords) */
-    add.l   %d0,%a1
-    cmp.l   %a0,%a2         /* runs %a0 up to last line bound */
-    jhi     .lines_lo8_loop
-
-    jra     .lines_lo8_end  /* handle trailing longwords */
-
-#ifdef FULLSPEED
-
-    /* word aligned destination (line + 2/6/10/14): head */
-.lines_do2_start:
-    cmp.l   %a0,%d0         /* any leading longwords? */
-    jls     .lines_do2_selector    /* no: jump to mainloop selector */
-
-    move.l  (%a0)+,%d7      /* load first longword */
-    swap    %d7             /* swap words */
-    move.w  %d7,(%a1)+      /* store high word */
-    cmp.l   %a0,%d0         /* any more longword? */
-    jls     .lines_do2_head_end    /* no: skip head loop */
-
-.lines_do2_head_loop:
-    move.l  %d7,%d6         /* move old longword away */
-    move.l  (%a0)+,%d7      /* load new longword */
-    swap    %d7             /* swap words */
-    move.w  %d7,%d6         /* combine high word with old low word */
-    move.l  %d6,(%a1)+      /* store longword */
-    cmp.l   %a0,%d0         /* runs %a0 up to first line bound */
-    jhi     .lines_do2_head_loop
-
-.lines_do2_head_end:
-    swap    %d7             /* undo swap */
-    move.w  %d7,(%a1)+      /* store word */
-
-.lines_do2_selector:
-    move.l  %a1,%d1
-    lsr.l   #2,%d1
-    moveq.l #3,%d0          /* mask */
-    and.l   %d0,%d1
-    moveq.l #16,%d0         /* address increment for one main loop pass */
-    jmp.l   (2,%pc,%d1.l*4) /* switch ((dest_addr >> 2) & 3) */
-    bra.w   .lines_lo2_start
-    bra.w   .lines_lo6_start
-    bra.w   .lines_lo10_start
- /* bra.w   .lines_lo14_start   implicit */
-
-    /* word aligned destination (line + 14): use line bursts in the loop */
-.lines_lo14_start:
-    movem.l (%a0),%d4-%d7   /* load first line */
-    add.l   %d0,%a0
-    swap    %d4             /* swap words of 1st long */
-    move.w  %d4,(%a1)+      /* store word */
-    jra     .lines_lo14_entry      /* jump into main loop */
-
-.lines_lo14_loop:
-    move.l  %d4,%d0         /* move old line away */
-    move.l  %d5,%d1
-    move.l  %d6,%d2
-    move.l  %d7,%d3
-    movem.l (%a0),%d4-%d7   /* load new line */
-    lea.l   (16,%a0),%a0
-    swap    %d4             /* swap words of 1st long */
-    move.w  %d4,%d3         /* combine 1st high word with old low word */
-    movem.l %d0-%d3,(%a1)   /* store line */
-    lea.l   (16,%a1),%a1
-.lines_lo14_entry:
-    swap    %d5             /* swap words of 2nd long */
-    move.w  %d5,%d4         /* combine 2nd high word with 1st low word */
-    swap    %d6             /* swap words of 3rd long */
-    move.w  %d6,%d5         /* combine 3rd high word with 2nd low word */
-    swap    %d7             /* swap words of 4th long */
-    move.w  %d7,%d6         /* combine 4th high word with 3rd low word */
-    cmp.l   %a0,%a2         /* runs %a0 up to last line bound */
-    jhi     .lines_lo14_loop
-
-    /* word aligned destination (line + 2/6/10/14): tail */
-.lines_lo14_end:
-    move.l  %d4,(%a1)+      /* store third last longword */
-.lines_lo10_end:
-    move.l  %d5,(%a1)+      /* store second last longword */
-.lines_lo6_end:
-    move.l  %d6,(%a1)+      /* store last longword */
-.lines_lo2_end:
-    lea.l   (12,%a2),%a2    /* readjust end address for doing longwords */
-    cmp.l   %a0,%a2         /* any trailing longwords? */
-    jls     .lines_do2_tail_end    /* no: skip tail loop */
-    
-.lines_do2_tail_loop:
-    move.l  %d7,%d6         /* move old longword away */
-    move.l  (%a0)+,%d7      /* load new longword */
-    swap    %d7             /* swap words */
-    move.w  %d7,%d6         /* combine high word with old low word */
-    move.l  %d6,(%a1)+      /* store longword */
-    cmp.l   %a0,%a2         /* runs %a0 up to last long bound */
-    jhi     .lines_do2_tail_loop
-
-.lines_do2_tail_end:
-    swap    %d7             /* undo swap */
-    move.w  %d7,(%a1)+      /* store last word */
-    jra     .lines_end  
-
-    /* word aligned destination (line + 2): use line bursts in the loop */
-.lines_lo2_start:
-    movem.l (%a0),%d4-%d7   /* load first line */
-    add.l   %d0,%a0
-    swap    %d4             /* swap words of 1st long */
-    move.w  %d4,(%a1)+      /* store high word */
-    swap    %d5             /* swap words of 2nd long */
-    move.w  %d5,%d4         /* combine 2nd high word with 1st low word */
-    swap    %d6             /* swap words of 3rd long */
-    move.w  %d6,%d5         /* combine 3nd high word with 2nd low word */
-    swap    %d7             /* swap words of 4th long */
-    move.w  %d7,%d6         /* combine 4th high word with 3rd low word */
-    move.l  %d4,(%a1)+      /* store 1st longword */
-    move.l  %d5,(%a1)+      /* store 2nd longword */
-    move.l  %d6,(%a1)+      /* store 3rd longword */
-    cmp.l   %a0,%a2         /* any full lines? */
-    jls     .lines_lo2_end  /* no: skip main loop */
-
-.lines_lo2_loop:
-    move.l  %d7,%d3         /* move last longword of old line away */
-    movem.l (%a0),%d4-%d7   /* load line */
-    add.l   %d0,%a0
-    swap    %d4             /* swap words of 1st long */
-    move.w  %d4,%d3         /* combine 1st high word with old low word */
-    swap    %d5             /* swap words of 2nd long */
-    move.w  %d5,%d4         /* combine 2nd high word with 1st low word */
-    swap    %d6             /* swap words of 3rd long */
-    move.w  %d6,%d5         /* combine 3rd high word with 2nd low word */
-    swap    %d7             /* swap words of 4th long */
-    move.w  %d7,%d6         /* combine 4th high word with 3rd low word */
-    movem.l %d3-%d6,(%a1)   /* store line */
-    add.l   %d0,%a1
-    cmp.l   %a0,%a2         /* runs %a0 up to last line bound */
-    jhi     .lines_lo2_loop
-
-    jra     .lines_lo2_end  /* handle trailing longwords */
-
-    /* word aligned destination (line + 6): use line bursts in the loop */
-.lines_lo6_start:
-    movem.l (%a0),%d4-%d7   /* load first line */
-    add.l   %d0,%a0
-    swap    %d4             /* swap words of 1st long */
-    move.w  %d4,(%a1)+      /* store high word */
-    swap    %d5             /* swap words of 2nd long */
-    move.w  %d5,%d4         /* combine 2nd high word with 1st low word */
-    swap    %d6             /* swap words of 3rd long */
-    move.w  %d6,%d5         /* combine 3rd high word with 2nd low word */
-    move.l  %d4,(%a1)+      /* store 1st longword */
-    move.l  %d5,(%a1)+      /* store 2nd longword */
-    jra     .lines_lo6_entry       /* jump into main loop */
-
-.lines_lo6_loop:
-    move.l  %d6,%d2         /* move last 2 longwords of old line away */
-    move.l  %d7,%d3
-    movem.l (%a0),%d4-%d7   /* load line */
-    add.l   %d0,%a0
-    swap    %d4             /* swap words of 1st long */
-    move.w  %d4,%d3         /* combine 1st high word with old low word */
-    swap    %d5             /* swap words of 2nd long */
-    move.w  %d5,%d4         /* combine 2nd high word with 1st low word */
-    swap    %d6             /* swap words of 3rd long */
-    move.w  %d6,%d5         /* combine 3rd high word with 2nd low word */
-    movem.l %d2-%d5,(%a1)   /* store line */
-    add.l   %d0,%a1
-.lines_lo6_entry:
-    swap    %d7             /* swap words of 4th long */
-    move.w  %d7,%d6         /* combine 4th high word with 3rd low word */
-    cmp.l   %a0,%a2         /* runs %a0 up to last line bound */
-    jhi     .lines_lo6_loop
-
-    jra     .lines_lo6_end  /* handle trailing longwords */
-
-    /* word aligned destination (line + 10): use line bursts in the loop */
-.lines_lo10_start:
-    movem.l (%a0),%d4-%d7   /* load first line */
-    add.l   %d0,%a0
-    swap    %d4             /* swap words of 1st long */
-    move.w  %d4,(%a1)+      /* store high word */
-    swap    %d5             /* swap words of 2nd long */
-    move.w  %d5,%d4         /* combine 2nd high word with 1st low word */
-    move.l  %d4,(%a1)+      /* store 1st longword */
-    jra     .lines_lo10_entry      /* jump into main loop */
-
-.lines_lo10_loop:
-    move.l  %d5,%d1         /* move last 3 longwords of old line away */
-    move.l  %d6,%d2
-    move.l  %d7,%d3
-    movem.l (%a0),%d4-%d7   /* load line */
-    add.l   %d0,%a0
-    swap    %d4             /* swap words of 1st long */
-    move.w  %d4,%d3         /* combine 1st high word with old low word */
-    swap    %d5             /* swap words of 2nd long */
-    move.w  %d5,%d4         /* combine 2nd high word with 1st low word */
-    movem.l %d1-%d4,(%a1)   /* store line */
-    add.l   %d0,%a1
-.lines_lo10_entry:
-    swap    %d6             /* swap words of 3rd long */
-    move.w  %d6,%d5         /* combine 3rd high word with 2nd low word */
-    swap    %d7             /* swap words of 4th long */
-    move.w  %d7,%d6         /* combine 4th high word with 3rd low word */
-    cmp.l   %a0,%a2         /* runs %a0 up to last line bound */
-    jhi     .lines_lo10_loop
-
-    jra     .lines_lo10_end /* handle trailing longwords */
-
-#else /* !FULLSPEED */
-
-    /* word aligned destination (long + 2): use line burst reads in the loop */
-.lines_do2_start:
-    cmp.l   %a0,%d0         /* any leading longwords? */
-    jhi     .lines_do2_head_start  /* yes: leading longword copy */
-
-    movem.l (%a0),%d4-%d7   /* load first line */
-    lea.l   (16,%a0),%a0
-    swap    %d4             /* swap words of 1st long */
-    move.w  %d4,(%a1)+      /* store high word */
-    jra     .lines_do2_entry       /* jump into main loop */
-
-.lines_do2_head_start:
-    move.l  (%a0)+,%d7      /* load first longword */
-    swap    %d7             /* swap words */
-    move.w  %d7,(%a1)+      /* store high word */
-    cmp.l   %a0,%d0         /* any full longword? */
-    jls     .lines_do2_loop /* no: skip head loop */
-
-.lines_do2_head_loop:
-    move.l  %d7,%d6         /* move old longword away */
-    move.l  (%a0)+,%d7      /* load new longword */
-    swap    %d7             /* swap words */
-    move.w  %d7,%d6         /* combine high word with old low word */
-    move.l  %d6,(%a1)+      /* store longword */
-    cmp.l   %a0,%d0         /* runs %a0 up to first line bound */
-    jhi     .lines_do2_head_loop
-
-.lines_do2_loop:
-    move.l  %d7,%d3         /* move last longword of old line away */
-    movem.l (%a0),%d4-%d7   /* load line */
-    lea.l   (16,%a0),%a0
-    swap    %d4             /* swap words of 1st long */
-    move.w  %d4,%d3         /* combine 1st high word with old low word */
-    move.l  %d3,(%a1)+      /* store 1st longword */
-.lines_do2_entry:
-    swap    %d5             /* swap words of 2nd long */
-    move.w  %d5,%d4         /* combine 2nd high word with 1st low word */
-    move.l  %d4,(%a1)+      /* store 2nd longword */
-    swap    %d6             /* swap words of 3rd long */
-    move.w  %d6,%d5         /* combine 3rd high word with 2nd low word */
-    move.l  %d5,(%a1)+      /* store 3rd longword */
-    swap    %d7             /* swap words of 4th long */
-    move.w  %d7,%d6         /* combine 4th high word with 3rd low word */
-    move.l  %d6,(%a1)+      /* store 4th longword */
-    cmp.l   %a0,%a2         /* runs %a0 up to last line bound */
-    jhi     .lines_do2_loop
-
-.lines_do2_end:
-    lea.l   (12,%a2),%a2    /* readjust end address for doing longwords */
-    cmp.l   %a0,%a2         /* any trailing longwords? */
-    jls     .lines_do2_tail_end    /* no: skip tail loop */
-    
-.lines_do2_tail_loop:
-    move.l  %d7,%d6         /* move old longword away */
-    move.l  (%a0)+,%d7      /* load new longword */
-    swap    %d7             /* swap words */
-    move.w  %d7,%d6         /* combine high word with old low word */
-    move.l  %d6,(%a1)+      /* store longword */
-    cmp.l   %a0,%a2         /* runs %a0 up to last long bound */
-    jhi     .lines_do2_tail_loop
-
-.lines_do2_tail_end:
-    swap    %d7             /* undo swap */
-    move.w  %d7,(%a1)+      /* store last word */
- /* jra     .lines_end    implicit */
-
-#endif /* !FULLSPEED */
-
-.lines_end:
-    addq.l  #3,%a2          /* readjust end address */
-    move.l  %a2,%d1         /* end address in %d1 again */
-    movem.l (%sp),%d2-%d7/%a2      /* restore registers */
-    lea.l   (28,%sp),%sp
-    jra     .bytes2_start   /* jump to trailing byte loop */
-
-.long_start:
-    subq.l  #3,%d1          /* adjust end address for doing 4 bytes/ pass */
-
-    /* longword copy loop - no lines */
-.long_loop:
-    move.l  (%a0)+,(%a1)+   /* copy longword (write can be unaligned) */
-    cmp.l   %a0,%d1         /* runs %a0 up to last long bound */
-    jhi     .long_loop
-
-    addq.l  #3,%d1          /* readjust end address */
-    cmp.l   %a0,%d1         /* any bytes left? */
-    jls     .bytes2_end     /* no: skip trailing byte loop */
-
-    /* trailing byte loop */
-.bytes2_loop:
-    move.b  (%a0)+,(%a1)+   /* copy byte */
-.bytes2_start:
-    cmp.l   %a0,%d1         /* runs %a0 up to end address */
-    jhi     .bytes2_loop
-
-.bytes2_end:
-    move.l  (4,%sp),%d0     /* return destination */
-    rts
-
-.end:
-    .size   memcpy,.end-memcpy
diff --git a/firmware/target/coldfire/memmove-coldfire.S b/firmware/target/coldfire/memmove-coldfire.S
deleted file mode 100644
index 736cd619e1..0000000000
--- a/firmware/target/coldfire/memmove-coldfire.S
+++ /dev/null
@@ -1,670 +0,0 @@
-/***************************************************************************
- *             __________               __   ___.
- *   Open      \______   \ ____   ____ |  | _\_ |__   _______  ___
- *   Source     |       _//  _ \_/ ___\|  |/ /| __ \ /  _ \  \/  /
- *   Jukebox    |    |   (  <_> )  \___|    < | \_\ (  <_> > <  <
- *   Firmware   |____|_  /\____/ \___  >__|_ \|___  /\____/__/\_ \
- *                     \/            \/     \/    \/            \/
- * $Id$
- *
- * Copyright (C) 2006 by Jens Arnold
- *
- * This program is free software; you can redistribute it and/or
- * modify it under the terms of the GNU General Public License
- * as published by the Free Software Foundation; either version 2
- * of the License, or (at your option) any later version.
- *
- * This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
- * KIND, either express or implied.
- *
- ****************************************************************************/
-#include "config.h"
-
-    .section    .icode,"ax",@progbits
-
-#define FULLSPEED /* use burst writing for word aligned destinations */
-    .align  2
-    .global memmove
-    .type   memmove,@function
-
-/* Moves <length> bytes of data in memory from <source> to <dest>
- * Regions may overlap.
- * This version is optimized for speed, and needs the corresponding memcpy
- * implementation for the forward copy branch.
- *
- * arguments:
- *  (4,%sp)  - destination address
- *  (8,%sp)  - source address
- *  (12,%sp) - length
- *
- * return value:
- *  %d0 - destination address (like ANSI version)
- *
- * register usage:
- *  %a0 - current source address
- *  %a1 - current dest address
- *  %a2 - source start address (in line-copy loops)
- *  %d0 - source start address (byte and longword copy) / data / scratch
- *  %d1 - data / scratch
- *  %d2 - data / scratch
- *  %d3..%d7 - data
- *
- * For maximum speed this routine reads and writes whole lines using burst
- * move (movem.l) where possible. For byte aligned destinations (long-1 and
- * long-3) it writes longwords only. Same goes for word aligned destinations
- * if FULLSPEED is undefined.
- */
-memmove:
-    move.l  (4,%sp),%a1     /* Destination */
-    move.l  (8,%sp),%a0     /* Source */
-    move.l  (12,%sp),%d1    /* Length */
-
-    cmp.l   %a0,%a1
-    bhi.b   .backward       /* dest > src -> backward copy */
-    jmp     __memcpy_fwd_entry
-
-.backward:
-    move.l  %a0,%d0         /* %d0 = source start */
-    add.l   %d1,%a0         /* %a0 = source end */
-    add.l   %d1,%a1         /* %a1 = destination end */
-
-    move.l  %a0,%d1
-    and.l   #0xFFFFFFFC,%d1 /* %d1 = last source long bound */
-    subq.l  #4,%d1
-    cmp.l   %d0,%d1         /* at least one aligned longword to copy? */
-    blo.w   .bytes2r_start
-
-    addq.l  #4,%d1          /* %d1 = last source long bound */
-    cmp.l   %d1,%a0         /* any bytes to copy */
-    jls     .bytes1r_end    /* no: skip byte loop */
-    
-    /* leading byte loop: copies 0..3 bytes */
-.bytes1r_loop:
-    move.b  -(%a0),-(%a1)   /* copy byte */
-    cmp.l   %d1,%a0         /* runs %a0 down to last long bound */
-    jhi     .bytes1r_loop
-
-.bytes1r_end:
-    moveq.l #-16,%d1
-    add.l   %a0,%d1
-    and.l   #0xFFFFFFF0,%d1 /* %d1 = last source line bound - 16 */
-    cmp.l   %d0,%d1         /* at least one aligned line to copy? */
-    blo.w   .longr_start    /* no: jump to longword copy loop */
-    
-    lea.l   (-28,%sp),%sp   /* free up some registers */
-    movem.l %d2-%d7/%a2,(%sp)
-
-    moveq.l #16,%d2
-    add.l   %d2,%d1         /* %d1 = last source line bound */
-    move.l  %d0,%a2         /* %a2 = start address */
-    lea.l   (15,%a2),%a2    /* adjust start address for loops doing 16 bytes/pass */
-    move.l  %a1,%d0
-    moveq.l #3,%d2          /* mask */
-    and.l   %d2,%d0
-    jmp.l   (2,%pc,%d0.l*4) /* switch (dest_addr & 3) */
-    bra.w   .lines_do0r_start
-    bra.w   .lines_do1r_start
-    bra.w   .lines_do2r_start
- /* bra.w   .lines_do3r_start   implicit */
-
-    /* byte aligned destination (long - 1): use line burst reads in main loop */
-.lines_do3r_start:
-    moveq.l #24,%d0         /* shift count for shifting by 3 bytes */
-    cmp.l   %d1,%a0         /* any leading longwords? */
-    jhi     .lines_do3r_head_start  /* yes: leading longword copy */
-    
-    lea.l   (-16,%a0),%a0
-    movem.l (%a0),%d3-%d6   /* load initial line */
-    move.l  %d6,%d2         /* last longword, bytes 3210 */
-    move.b  %d2,-(%a1)      /* store byte */
-    lsr.l   #8,%d2          /* last longword, bytes .321 */
-    move.w  %d2,-(%a1)      /* store word */
-    jra     .lines_do3r_entry
-    
-.lines_do3r_head_start:
-    move.l  -(%a0),%d3      /* load initial longword */
-    move.l  %d3,%d2         /* bytes 3210 */
-    move.b  %d2,-(%a1)      /* store byte */
-    lsr.l   #8,%d2          /* bytes .321 */
-    move.w  %d2,-(%a1)      /* store word */
-    jra     .lines_do3r_head_entry
-    
-.lines_do3r_head_loop:
-    move.l  %d3,%d4         /* move old longword away */
-    move.l  -(%a0),%d3      /* load new longword */
-    move.l  %d3,%d2     
-    lsl.l   #8,%d2          /* get bytes 210. */
-    or.l    %d2,%d4         /* combine with old high byte */
-    move.l  %d4,-(%a1)      /* store longword */
-.lines_do3r_head_entry:
-    lsr.l   %d0,%d3         /* shift down high byte */
-    cmp.l   %d1,%a0         /* run %a0 down to last line bound */
-    jhi     .lines_do3r_head_loop
-
-.lines_do3r_loop:
-    move.l  %d3,%d7         /* move first longword of last line away */
-    lea.l   (-16,%a0),%a0
-    movem.l (%a0),%d3-%d6   /* load new line */
-    move.l  %d6,%d2
-    lsl.l   #8,%d2          /* get bytes 210. of 4th longword */
-    or.l    %d2,%d7         /* combine with high byte of old longword */
-    move.l  %d7,-(%a1)      /* store longword */
-.lines_do3r_entry:
-    lsr.l   %d0,%d6         /* shift down high byte */
-    move.l  %d5,%d2
-    lsl.l   #8,%d2          /* get bytes 210. of 3rd longword */
-    or.l    %d2,%d6         /* combine with high byte of 4th longword */
-    move.l  %d6,-(%a1)      /* store longword */
-    lsr.l   %d0,%d5         /* shift down high byte */
-    move.l  %d4,%d2
-    lsl.l   #8,%d2          /* get bytes 210. of 2nd longword */
-    or.l    %d2,%d5         /* combine with high byte or 3rd longword */
-    move.l  %d5,-(%a1)      /* store longword */
-    lsr.l   %d0,%d4         /* shift down high byte */
-    move.l  %d3,%d2
-    lsl.l   #8,%d2          /* get bytes 210. of 1st longword */
-    or.l    %d2,%d4         /* combine with high byte of 2nd longword */
-    move.l  %d4,-(%a1)      /* store longword */
-    lsr.l   %d0,%d3         /* shift down high byte */
-    cmp.l   %a2,%a0         /* run %a0 down to first line bound */
-    jhi     .lines_do3r_loop
-
-    lea.l   (-12,%a2),%a2   /* readjust start address for doing longwords */
-    cmp.l   %a2,%a0         /* any trailing longwords? */
-    jls     .lines_do3r_tail_end    /* no: just store last high byte */
-
-.lines_do3r_tail_loop:
-    move.l  %d3,%d4         /* move old longword away */
-    move.l  -(%a0),%d3      /* load new longword */
-    move.l  %d3,%d2   
-    lsl.l   #8,%d2          /* get bytes 210. */
-    or.l    %d2,%d4         /* combine with old high byte */
-    move.l  %d4,-(%a1)      /* store longword */
-    lsr.l   %d0,%d3         /* shift down high byte */
-    cmp.l   %a2,%a0         /* run %a0 down to first long bound */
-    jhi     .lines_do3r_tail_loop
-    
-.lines_do3r_tail_end:
-    move.b  %d3,-(%a1)      /* store shifted-down high byte */
-    jra     .linesr_end
-    
-    /* byte aligned destination (long - 3): use line burst reads in main loop */
-.lines_do1r_start:
-    moveq.l #24,%d0         /* shift count for shifting by 3 bytes */
-    cmp.l   %d1,%a0         /* any leading longwords? */
-    jhi     .lines_do1r_head_start  /* yes: leading longword copy */
-
-    lea.l   (-16,%a0),%a0
-    movem.l (%a0),%d3-%d6   /* load initial line */
-    move.b  %d6,-(%a1)      /* store low byte of last longword */
-    jra     .lines_do1r_entry
-    
-.lines_do1r_head_start:
-    move.l  -(%a0),%d3      /* load initial longword */
-    move.b  %d3,-(%a1)      /* store low byte */
-    jra     .lines_do1r_head_entry
-
-.lines_do1r_head_loop:
-    move.l  %d3,%d4         /* move old longword away */
-    move.l  -(%a0),%d3      /* load new longword */
-    move.l  %d3,%d2
-    lsl.l   %d0,%d2         /* get low byte */
-    or.l    %d2,%d4         /* combine with old bytes .321 */
-    move.l  %d4,-(%a1)      /* store longword */
-.lines_do1r_head_entry:
-    lsr.l   #8,%d3          /* get bytes .321 */
-    cmp.l   %d1,%a0         /* run %a0 down to last line bound */
-    jhi     .lines_do1r_head_loop
-
-.lines_do1r_loop:
-    move.l  %d3,%d7         /* move first longword of old line away */
-    lea.l   (-16,%a0),%a0
-    movem.l (%a0),%d3-%d6   /* load new line */
-    move.l  %d6,%d2
-    lsl.l   %d0,%d2         /* get low byte of 4th longword */
-    or.l    %d2,%d7         /* combine with bytes .321 of old longword */
-    move.l  %d7,-(%a1)      /* store longword */
-.lines_do1r_entry:
-    lsr.l   #8,%d6          /* get bytes .321 */
-    move.l  %d5,%d2
-    lsl.l   %d0,%d2         /* get low byte of 3rd longword */
-    or.l    %d2,%d6         /* combine with bytes .321 of 4th longword */
-    move.l  %d6,-(%a1)      /* store longword */
-    lsr.l   #8,%d5          /* get bytes .321 */
-    move.l  %d4,%d2
-    lsl.l   %d0,%d2         /* get low byte of 2nd longword */
-    or.l    %d2,%d5         /* combine with bytes .321 of 3rd longword */
-    move.l  %d5,-(%a1)      /* store longword */
-    lsr.l   #8,%d4          /* get bytes .321 */
-    move.l  %d3,%d2
-    lsl.l   %d0,%d2         /* get low byte of 1st longword */
-    or.l    %d2,%d4         /* combine with bytes .321 of 2nd longword */
-    move.l  %d4,-(%a1)      /* store longword */
-    lsr.l   #8,%d3          /* get bytes .321 */
-    cmp.l   %a2,%a0         /* run %a0 down to first line bound */
-    jhi     .lines_do1r_loop
-
-    lea.l   (-12,%a2),%a2   /* readjust start address for doing longwords */
-    cmp.l   %a2,%a0         /* any trailing longwords? */
-    jls     .lines_do1r_tail_end    /* no: just store last high byte */
-
-.lines_do1r_tail_loop:
-    move.l  %d3,%d4         /* move old longword away */
-    move.l  -(%a0),%d3      /* load new longword */
-    move.l  %d3,%d2
-    lsl.l   %d0,%d2         /* get low byte */
-    or.l    %d2,%d4         /* combine with old bytes .321 */
-    move.l  %d4,-(%a1)      /* store longword */
-    lsr.l   #8,%d3          /* get bytes .321 */
-    cmp.l   %a2,%a0         /* run %a0 down to first long bound */
-    jhi     .lines_do1r_tail_loop
-    
-.lines_do1r_tail_end:
-    move.w  %d3,-(%a1)      /* store word 21 */
-    swap    %d3
-    move.b  %d3,-(%a1)      /* store byte 3 */
-    jra     .linesr_end
-
-    /* long aligned destination (line - 0/4/8/12): head */
-.lines_do0r_head_loop:
-    move.l  -(%a0),-(%a1)   /* copy longword */
-.lines_do0r_start:
-    cmp.l   %d1,%a0         /* run %a0 down to last line bound */
-    jhi     .lines_do0r_head_loop
-
-.lines_do0r_head_end:
-    move.l  %a1,%d1
-    lsr.l   #2,%d1
-    moveq.l #3,%d0          /* mask */
-    and.l   %d0,%d1
-    moveq.l #16,%d0         /* address decrement for one main loop pass */
-    jmp.l   (2,%pc,%d1.l*2) /* switch ((dest_addr >> 2) & 3) */
-    bra.b   .lines_lo0r_start
-    bra.b   .lines_lo4r_start
-    bra.b   .lines_lo8r_start
- /* bra.b   .lines_lo12r_start   implicit */
-
-    /* long aligned destination (line - 4): use line bursts in the loop */
-.lines_lo12r_start:
-    sub.l   %d0,%a0
-    movem.l (%a0),%d1-%d4   /* load initial line */
-    move.l  %d4,-(%a1)      /* store 4th longword */
-    move.l  %d3,-(%a1)      /* store 3rd longword */
-    move.l  %d2,-(%a1)      /* store 2nd longword */
-    cmp.l   %a2,%a0         /* any full lines? */
-    jls     .lines_lo12r_end   /* no: skip main loop */
-    
-.lines_lo12r_loop:
-    move.l  %d1,%d5         /* move first longword of old line away */
-    sub.l   %d0,%a0
-    movem.l (%a0),%d1-%d4   /* load new line */
-    sub.l   %d0,%a1
-    movem.l %d2-%d5,(%a1)   /* store line (1 old + 3 new longwords */
-    cmp.l   %a2,%a0         /* run %a0 down to first line bound */
-    jhi     .lines_lo12r_loop
-
-    jra     .lines_lo12r_end   /* handle trailing longwords */
-
-    /* line aligned destination: use line bursts in the loop */
-.lines_lo0r_start:
-.lines_lo0r_loop:
-    sub.l   %d0,%a0
-    movem.l (%a0),%d1-%d4   /* load line */
-    sub.l   %d0,%a1
-    movem.l %d1-%d4,(%a1)   /* store line */
-    cmp.l   %a2,%a0         /* run %a0 down to first line bound */
-    jhi     .lines_lo0r_loop
-
-    jra     .lines_lo0r_end /* handle trailing longwords */
-
-    /* long aligned destination (line - 8): use line bursts in the loop */
-.lines_lo8r_start:
-    sub.l   %d0,%a0
-    movem.l (%a0),%d1-%d4   /* load initial line */
-    move.l  %d4,-(%a1)      /* store 4th longword */
-    move.l  %d3,-(%a1)      /* store 3rd longword */
-    cmp.l   %a2,%a0         /* any full lines? */
-    jls     .lines_lo8r_end /* no: skip main loop */
-    
-.lines_lo8r_loop:
-    move.l  %d2,%d6         /* move first 2 longwords of old line away */
-    move.l  %d1,%d5         
-    sub.l   %d0,%a0
-    movem.l (%a0),%d1-%d4   /* load new line */
-    sub.l   %d0,%a1
-    movem.l %d3-%d6,(%a1)   /* store line (2 old + 2 new longwords */
-    cmp.l   %a2,%a0         /* run %a0 down to first line bound */
-    jhi     .lines_lo8r_loop
-
-    jra     .lines_lo8r_end /* handle trailing longwords */
-
-    /* long aligned destination (line - 12): use line bursts in the loop */
-.lines_lo4r_start:
-    sub.l   %d0,%a0
-    movem.l (%a0),%d1-%d4   /* load initial line */
-    move.l  %d4,-(%a1)      /* store 4th longword */
-    cmp.l   %a2,%a0         /* any full lines? */
-    jls     .lines_lo4r_end /* no: skip main loop */
-    
-.lines_lo4r_loop:
-    move.l  %d3,%d7         /* move first 3 longwords of old line away */
-    move.l  %d2,%d6         
-    move.l  %d1,%d5         
-    sub.l   %d0,%a0
-    movem.l (%a0),%d1-%d4   /* load new line */
-    sub.l   %d0,%a1
-    movem.l %d4-%d7,(%a1)   /* store line (3 old + 1 new longwords */
-    cmp.l   %a2,%a0         /* run %a0 down to first line bound */
-    jhi     .lines_lo4r_loop
-
-    /* long aligned destination (line - 0/4/8/12): tail */
-.lines_lo4r_end:
-    move.l  %d3,-(%a1)      /* store 3rd last longword */
-.lines_lo8r_end:
-    move.l  %d2,-(%a1)      /* store 2nd last longword */
-.lines_lo12r_end:
-    move.l  %d1,-(%a1)      /* store last longword */
-.lines_lo0r_end:
-    lea.l   (-12,%a2),%a2   /* readjust end address for doing longwords */
-    cmp.l   %a2,%a0         /* any trailing longwords? */
-    jls     .linesr_end     /* no: get outta here */
-
-.lines_do0r_tail_loop:
-    move.l  -(%a0),-(%a1)   /* copy longword */
-    cmp.l   %a2,%a0         /* run %a0 down to first long bound */
-    jhi     .lines_do0r_tail_loop
-
-    jra     .linesr_end
-    
-#ifdef FULLSPEED
-    /* word aligned destination (line - 2/6/10/14): head */
-.lines_do2r_start:
-    cmp.l   %d1,%a0         /* any leading longwords? */
-    jls     .lines_do2r_selector    /* no: jump to mainloop selector */
-    
-    move.l  -(%a0),%d3      /* load initial longword */
-    move.w  %d3,-(%a1)      /* store low word */
-    cmp.l   %d1,%a0         /* any more longwords? */
-    jls     .lines_do2r_head_end    /* no: skip head loop */
-    
-.lines_do2r_head_loop:
-    move.l  %d3,%d4         /* move old longword away */
-    move.l  -(%a0),%d3      /* load new longword */
-    move.w  %d3,%d4         /* combine low word with old high word */
-    swap    %d4             /* swap words */
-    move.l  %d4,-(%a1)      /* store longword */
-    cmp.l   %d1,%a0         /* run %a0 down to last line bound */
-    jhi     .lines_do2r_head_loop
-    
-.lines_do2r_head_end:
-    swap    %d3             /* get high word */
-    move.w  %d3,-(%a1)      /* and store it */
-    
-.lines_do2r_selector:
-    move.l  %a1,%d1
-    lsr.l   #2,%d1
-    moveq.l #3,%d0          /* mask */
-    and.l   %d0,%d1
-    moveq.l #16,%d7         /* address decrement for one main loop pass */
-    jmp.l   (2,%pc,%d1.l*4) /* switch ((dest_addr >> 2) & 3) */
-    bra.w   .lines_lo2r_start
-    bra.w   .lines_lo6r_start
-    bra.w   .lines_lo10r_start
- /* bra.w   .lines_lo14r_start   implicit */
-
-    /* word aligned destination (line - 2): use line bursts in the loop */
-.lines_lo14r_start:
-    sub.l   %d7,%a0
-    movem.l (%a0),%d0-%d3   /* load initial line */
-    move.w  %d3,-(%a1)      /* store last low word */
-    move.w  %d2,%d3         /* combine 3rd low word with 4th high word */
-    swap    %d3             /* swap words of 3rd long */
-    move.w  %d1,%d2         /* combine 2nd low word with 3rd high word */
-    swap    %d2             /* swap words of 2nd long */
-    move.w  %d0,%d1         /* combine 1st low word with 2nd high word */
-    swap    %d1             /* swap words of 1st long */
-    move.l  %d3,-(%a1)      /* store 3rd longword */
-    move.l  %d2,-(%a1)      /* store 2nd longword */
-    move.l  %d1,-(%a1)      /* store 1st longword */
-    cmp.l   %a2,%a0         /* any full lines? */
-    jls     .lines_lo14r_end   /* no: skip main loop */
-
-.lines_lo14r_loop:
-    move.l  %d0,%d4         /* move first longword of old line away */
-    sub.l   %d7,%a0
-    movem.l (%a0),%d0-%d3   /* load line */
-    move.w  %d3,%d4         /* combine 4th low word with old high word */
-    swap    %d4             /* swap words of 4th long */
-    move.w  %d2,%d3         /* combine 3rd low word with 4th high word */
-    swap    %d3             /* swap words of 3rd long */
-    move.w  %d1,%d2         /* combine 2nd low word with 3rd high word */
-    swap    %d2             /* swap words of 2nd long */
-    move.w  %d0,%d1         /* combine 1st low word with 2nd high word */
-    swap    %d1             /* swap words of 1st long */
-    sub.l   %d7,%a1
-    movem.l %d1-%d4,(%a1)   /* store line */
-    cmp.l   %a2,%a0         /* run %a0 down to first line bound */
-    jhi     .lines_lo14r_loop
-    
-    jra     .lines_lo14r_end   /* handle trailing longwords */
-
-    /* word aligned destination (line - 6): use line bursts in the loop */
-.lines_lo10r_start:
-    sub.l   %d7,%a0
-    movem.l (%a0),%d0-%d3   /* load initial line */
-    move.w  %d3,-(%a1)      /* store last low word */
-    move.w  %d2,%d3         /* combine 3rd low word with 4th high word */
-    swap    %d3             /* swap words of 3rd long */
-    move.w  %d1,%d2         /* combine 2nd low word with 3rd high word */
-    swap    %d2             /* swap words of 2nd long */
-    move.l  %d3,-(%a1)      /* store 3rd longword */
-    move.l  %d2,-(%a1)      /* store 2nd longword */
-    jra     .lines_lo10r_entry /* jump into main loop */
-    
-.lines_lo10r_loop:
-    move.l  %d0,%d4         /* move first 2 longwords of old line away */
-    move.l  %d1,%d5
-    sub.l   %d7,%a0
-    movem.l (%a0),%d0-%d3   /* load line */
-    move.w  %d3,%d4         /* combine 4th low word with old high word */
-    swap    %d4             /* swap words of 4th long */
-    move.w  %d2,%d3         /* combine 3rd low word with 4th high word */
-    swap    %d3             /* swap words of 3rd long */
-    move.w  %d1,%d2         /* combine 2nd low word with 3rd high word */
-    swap    %d2             /* swap words of 2nd long */
-    sub.l   %d7,%a1
-    movem.l %d2-%d5,(%a1)   /* store line */
-.lines_lo10r_entry:
-    move.w  %d0,%d1         /* combine 1st low word with 2nd high word */
-    swap    %d1             /* swap words of 1st long */
-    cmp.l   %a2,%a0         /* run %a0 down to first line bound */
-    jhi     .lines_lo10r_loop
-    
-    jra     .lines_lo10r_end   /* handle trailing longwords */
-
-    /* word aligned destination (line - 10): use line bursts in the loop */
-.lines_lo6r_start:
-    sub.l   %d7,%a0
-    movem.l (%a0),%d0-%d3   /* load initial line */
-    move.w  %d3,-(%a1)      /* store last low word */
-    move.w  %d2,%d3         /* combine 3rd low word with 4th high word */
-    swap    %d3             /* swap words of 3rd long */
-    move.l  %d3,-(%a1)      /* store 3rd longword */
-    jra     .lines_lo6r_entry  /* jump into main loop */
-    
-.lines_lo6r_loop:
-    move.l  %d0,%d4         /* move first 3 longwords of old line away */
-    move.l  %d1,%d5
-    move.l  %d2,%d6
-    sub.l   %d7,%a0
-    movem.l (%a0),%d0-%d3   /* load line */
-    move.w  %d3,%d4         /* combine 4th low word with old high word */
-    swap    %d4             /* swap words of 4th long */
-    move.w  %d2,%d3         /* combine 3rd low word with 4th high word */
-    swap    %d3             /* swap words of 3rd long */
-    sub.l   %d7,%a1
-    movem.l %d3-%d6,(%a1)   /* store line */
-.lines_lo6r_entry:
-    move.w  %d1,%d2         /* combine 2nd low word with 3rd high word */
-    swap    %d2             /* swap words of 2nd long */
-    move.w  %d0,%d1         /* combine 1st low word with 2nd high word */
-    swap    %d1             /* swap words of 1st long */
-    cmp.l   %a2,%a0         /* run %a0 down to first line bound */
-    jhi     .lines_lo6r_loop
-    
-    jra     .lines_lo6r_end /* handle trailing longwords */
-
-    /* word aligned destination (line - 14): use line bursts in the loop */
-.lines_lo2r_start:
-    sub.l   %d7,%a0
-    movem.l (%a0),%d0-%d3   /* load initial line */
-    move.w  %d3,-(%a1)      /* store last low word */
-    jra     .lines_lo2r_entry  /* jump into main loop */
-    
-.lines_lo2r_loop:
-    move.l  %d0,%d4         /* move old line away */
-    move.l  %d1,%d5
-    move.l  %d2,%d6
-    move.l  %d3,%d7
-    lea.l   (-16,%a0),%a0
-    movem.l (%a0),%d0-%d3   /* load line */
-    move.w  %d3,%d4         /* combine 4th low word with old high word */
-    swap    %d4             /* swap words of 4th long */
-    lea.l   (-16,%a1),%a1
-    movem.l %d4-%d7,(%a1)   /* store line */
-.lines_lo2r_entry:
-    move.w  %d2,%d3         /* combine 3rd low word with 4th high word */
-    swap    %d3             /* swap words of 3rd long */
-    move.w  %d1,%d2         /* combine 2nd low word with 3rd high word */
-    swap    %d2             /* swap words of 2nd long */
-    move.w  %d0,%d1         /* combine 1st low word with 2nd high word */
-    swap    %d1             /* swap words of 1st long */
-    cmp.l   %a2,%a0         /* run %a0 down to first line bound */
-    jhi     .lines_lo2r_loop
-    
-    /* word aligned destination (line - 2/6/10/14): tail */
-.lines_lo2r_end:
-    move.l  %d3,-(%a1)      /* store third last longword */
-.lines_lo6r_end:
-    move.l  %d2,-(%a1)      /* store second last longword */
-.lines_lo10r_end:
-    move.l  %d1,-(%a1)      /* store last longword */
-.lines_lo14r_end:
-    lea.l   (-12,%a2),%a2   /* readjust start address for doing longwords */
-    cmp.l   %a2,%a0         /* any trailing longwords? */
-    jls     .lines_do2r_tail_end    /* no: skip tail loop */
-
-.lines_do2r_tail_loop:
-    move.l  %d0,%d1         /* move old longword away */
-    move.l  -(%a0),%d0      /* load new longword */
-    move.w  %d0,%d1         /* combine low word with old high word */
-    swap    %d1             /* swap words */
-    move.l  %d1,-(%a1)      /* store longword */
-    cmp.l   %a2,%a0         /* run %a0 down to first long bound */
-    jhi     .lines_do2r_tail_loop
-    
-.lines_do2r_tail_end:
-    swap    %d0             /* get final high word */
-    move.w  %d0,-(%a1)      /* store it */
- /* jra     .linesr_end    implicit */
-
-#else /* !FULLSPEED */
-
-    /* word aligned destination (long - 2): use line burst reads in the loop */
-.lines_do2r_start:
-    cmp.l   %d1,%a0         /* any leading longwords? */
-    jhi     .lines_do2r_head_start  /* yes: leading longword copy */
-
-    lea.l   (-16,%a0),%a0
-    movem.l (%a0),%d3-%d6   /* load initial line */
-    move.w  %d6,-(%a1)      /* store last low word */
-    jra     .lines_do2r_entry  /* jump into main loop */
-    
-.lines_do2r_head_start:
-    move.l  -(%a0),%d3      /* load initial longword */
-    move.w  %d3,-(%a1)      /* store low word */
-    cmp.l   %d1,%a0         /* any full longword? */
-    jls     .lines_do2r_loop   /* no: skip head loop */
-    
-.lines_do2r_head_loop:
-    move.l  %d3,%d4         /* move old longword away */
-    move.l  -(%a0),%d3      /* load new longword */
-    move.w  %d3,%d4         /* combine low word with old high word */
-    swap    %d4             /* swap words */
-    move.l  %d4,-(%a1)      /* store longword */
-    cmp.l   %d1,%a0         /* run %a0 down to last line bound */
-    jhi     .lines_do2r_head_loop
-    
-.lines_do2r_loop:
-    move.l  %d3,%d7         /* move first longword of old line away */
-    lea.l   (-16,%a0),%a0
-    movem.l (%a0),%d3-%d6   /* load line */
-    move.w  %d6,%d7         /* combine 4th low word with old high word */
-    swap    %d7             /* swap words of 4th long */
-    move.l  %d7,-(%a1)      /* store 4th longword */
-.lines_do2r_entry:
-    move.w  %d5,%d6         /* combine 3rd low word with 4th high word */
-    swap    %d6             /* swap words of 3rd long */
-    move.l  %d6,-(%a1)      /* store 3rd longword */
-    move.w  %d4,%d5         /* combine 2nd low word with 3rd high word */
-    swap    %d5             /* swap words of 2nd long */
-    move.l  %d5,-(%a1)      /* store 2nd longword */
-    move.w  %d3,%d4         /* combine 1st low word with 2nd high word */
-    swap    %d4             /* swap words of 1st long */
-    move.l  %d4,-(%a1)      /* store 1st longword */
-    cmp.l   %a2,%a0         /* run %a0 down to first line bound */
-    jhi     .lines_do2r_loop
-
-.lines_do2r_end:
-    lea.l   (-12,%a2),%a2   /* readjust start address for doing longwords */
-    cmp.l   %a2,%a0         /* any trailing longwords? */
-    jls     .lines_do2r_tail_end   /* no: skip tail loop */
-    
-.lines_do2r_tail_loop:
-    move.l  %d3,%d4         /* move old longword away */
-    move.l  -(%a0),%d3      /* load new longword */
-    move.w  %d3,%d4         /* combine low word with old high word */
-    swap    %d4             /* swap words */
-    move.l  %d4,-(%a1)      /* store longword */
-    cmp.l   %a2,%a0         /* run %a0 down to first long bound */
-    jhi     .lines_do2r_tail_loop
-
-.lines_do2r_tail_end:
-    swap    %d3             /* get final high word */
-    move.w  %d3,-(%a1)      /* store it */
- /* jra     .linesr_end    implicit */
-
-#endif /* !FULLSPEED */
-
-.linesr_end:
-    subq.l  #3,%a2          /* readjust end address */
-    move.l  %a2,%d0         /* start address in %d0 again */
-    movem.l (%sp),%d2-%d7/%a2      /* restore registers */
-    lea.l   (28,%sp),%sp
-    jra     .bytes2r_start  /* jump to trailing byte loop */
-
-.longr_start:
-    addq.l  #3,%d0          /* adjust start address for doing 4 bytes/ pass */
-
-    /* longword copy loop - no lines */
-.longr_loop:
-    move.l  -(%a0),-(%a1)   /* copy longword (write can be unaligned) */
-    cmp.l   %d0,%a0         /* runs %a0 down to first long bound */
-    jhi     .longr_loop
-
-    subq.l  #3,%d0          /* readjust start address */
-    cmp.l   %d0,%a0         /* any bytes left? */
-    jls     .bytes2r_end    /* no: skip trailing byte loop */
-
-    /* trailing byte loop */
-.bytes2r_loop:
-    move.b  -(%a0),-(%a1)   /* copy byte */
-.bytes2r_start:
-    cmp.l   %d0,%a0         /* runs %a0 down to start address */
-    jhi     .bytes2r_loop
-
-.bytes2r_end:
-    rts                     /* returns start address */
-
-.end:
-    .size   memmove,.end-memmove
diff --git a/firmware/target/coldfire/memset-coldfire.S b/firmware/target/coldfire/memset-coldfire.S
deleted file mode 100644
index 839b305a05..0000000000
--- a/firmware/target/coldfire/memset-coldfire.S
+++ /dev/null
@@ -1,152 +0,0 @@
-/***************************************************************************
- *             __________               __   ___.
- *   Open      \______   \ ____   ____ |  | _\_ |__   _______  ___
- *   Source     |       _//  _ \_/ ___\|  |/ /| __ \ /  _ \  \/  /
- *   Jukebox    |    |   (  <_> )  \___|    < | \_\ (  <_> > <  <
- *   Firmware   |____|_  /\____/ \___  >__|_ \|___  /\____/__/\_ \
- *                     \/            \/     \/    \/            \/
- * $Id$
- *
- * Copyright (C) 2004 by Jens Arnold
- *
- * This program is free software; you can redistribute it and/or
- * modify it under the terms of the GNU General Public License
- * as published by the Free Software Foundation; either version 2
- * of the License, or (at your option) any later version.
- *
- * This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
- * KIND, either express or implied.
- *
- ****************************************************************************/
-#include "config.h"
-
-    .section    .icode,"ax",@progbits
-
-    .align      2
-    .global     memset
-    .type       memset,@function
-
-/* Fills a memory region with specified byte value
- * This version is optimized for speed
- *
- * arguments:
- *  (4,%sp)  - start address
- *  (8,%sp)  - data
- *  (12,%sp) - length
- *
- * return value:
- *  %d0 - start address (like ANSI version)
- *
- * register usage:
- *  %d0 - data (spread to all 4 bytes when using long stores)
- *  %d1 - temporary / data (for burst transfer)
- *  %d2 - data (for burst transfer)
- *  %d3 - data (for burst transfer)
- *  %a0 - start address
- *  %a1 - current address (runs down from end to start)
- *
- * For maximum speed this routine uses both long stores and burst mode,
- * storing whole lines with movem.l. The routine fills memory from end
- * to start in order to ease returning the start address.
- */
-memset:
-    move.l  (4,%sp),%a0     /* start address */
-    move.l  (8,%sp),%d0     /* data */
-    move.l  (12,%sp),%a1    /* length */
-    add.l   %a0,%a1         /* %a1 = end address */
-
-    move.l  %a0,%d1
-    addq.l  #7,%d1
-    and.l   #0xFFFFFFFC,%d1 /* %d1 = first long bound + 4 */
-    cmp.l   %d1,%a1         /* at least one aligned longword to fill? */
-    blo.b   .no_longs       /* no, jump directly to byte loop */
-
-    and.l   #0xFF,%d0       /* start: spread data to all 4 bytes */
-    move.l  %d0,%d1
-    lsl.l   #8,%d1
-    or.l    %d1,%d0         /* data now in 2 lower bytes of %d0 */
-    move.l  %d0,%d1
-    swap    %d0
-    or.l    %d1,%d0         /* data now in all 4 bytes of %d0 */
-
-    move.l  %a1,%d1
-    and.l   #0xFFFFFFFC,%d1 /* %d1 = last long bound */
-    cmp.l   %d1,%a1         /* any bytes to set? */
-    bls.b   .end_b1         /* no: skip byte loop */
-
-    /* leading byte loop: sets 0..3 bytes */
-.loop_b1:
-    move.b  %d0,-(%a1)      /* store byte */
-    cmp.l   %d1,%a1         /* runs %a1 down to last long bound */
-    bhi.b   .loop_b1
-    
-.end_b1:
-    moveq.l #31,%d1
-    add.l   %a0,%d1
-    and.l   #0xFFFFFFF0,%d1 /* %d1 = first line bound + 16 */
-    cmp.l   %d1,%a1         /* at least one full line to fill? */
-    blo.b   .no_lines       /* no, jump to longword loop */
-
-    mov.l   %a1,%d1
-    and.l   #0xFFFFFFF0,%d1 /* %d1 = last line bound */
-    cmp.l   %d1,%a1         /* any longwords to set? */
-    bls.b   .end_l1         /* no: skip longword loop */
-
-    /* leading longword loop: sets 0..3 longwords */
-.loop_l1:
-    move.l  %d0,-(%a1)      /* store longword */
-    cmp.l   %d1,%a1         /* runs %a1 down to last line bound */
-    bhi.b   .loop_l1
-
-.end_l1:
-    move.l  %d2,-(%sp)      /* free some registers */
-    move.l  %d3,-(%sp)
-
-    move.l  %d0,%d1         /* spread data to 4 data registers */
-    move.l  %d0,%d2
-    move.l  %d0,%d3
-    lea.l   (15,%a0),%a0    /* start address += 15, acct. for trl. data */
-    
-    /* main loop: set whole lines utilising burst mode */
-.loop_line:
-    lea.l   (-16,%a1),%a1   /* pre-decrement */
-    movem.l %d0-%d3,(%a1)   /* store line */
-    cmp.l   %a0,%a1         /* runs %a1 down to first line bound */
-    bhi.b   .loop_line
-
-    lea.l   (-15,%a0),%a0   /* correct start address */
-    move.l  (%sp)+,%d3      /* restore registers */
-    move.l  (%sp)+,%d2
-
-    move.l  %a0,%d1         /* %d1 = start address ... */
-    addq.l  #3,%d1          /* ... +3, account for possible trailing bytes */
-    cmp.l   %d1,%a1         /* any longwords left */
-    bhi.b   .loop_l2        /* yes: jump to longword loop */
-    bra.b   .no_longs       /* no: skip loop */
-
-.no_lines:
-    move.l  %a0,%d1         /* %d1 = start address ... */
-    addq.l  #3,%d1          /* ... +3, account for possible trailing bytes */
-
-    /* trailing longword loop */
-.loop_l2:
-    move.l  %d0,-(%a1)      /* store longword */
-    cmp.l   %d1,%a1         /* runs %a1 down to first long bound */
-    bhi.b   .loop_l2
-
-.no_longs:
-    cmp.l   %a0,%a1         /* any bytes left? */
-    bls.b   .end_b2         /* no: skip loop */
-
-    /* trailing byte loop */
-.loop_b2:
-    move.b  %d0,-(%a1)      /* store byte */
-    cmp.l   %a0,%a1         /* runs %a1 down to start address */
-    bhi.b   .loop_b2
-
-.end_b2:
-    move.l  %a0,%d0         /* return start address */
-    rts
-
-.end:
-    .size   memset,.end-memset
diff --git a/firmware/target/coldfire/memset16-coldfire.S b/firmware/target/coldfire/memset16-coldfire.S
deleted file mode 100644
index 1673038d03..0000000000
--- a/firmware/target/coldfire/memset16-coldfire.S
+++ /dev/null
@@ -1,146 +0,0 @@
-/***************************************************************************
- *             __________               __   ___.
- *   Open      \______   \ ____   ____ |  | _\_ |__   _______  ___
- *   Source     |       _//  _ \_/ ___\|  |/ /| __ \ /  _ \  \/  /
- *   Jukebox    |    |   (  <_> )  \___|    < | \_\ (  <_> > <  <
- *   Firmware   |____|_  /\____/ \___  >__|_ \|___  /\____/__/\_ \
- *                     \/            \/     \/    \/            \/
- * $Id$
- *
- * Copyright (C) 2006 by Jens Arnold
- *
- * This program is free software; you can redistribute it and/or
- * modify it under the terms of the GNU General Public License
- * as published by the Free Software Foundation; either version 2
- * of the License, or (at your option) any later version.
- *
- * This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
- * KIND, either express or implied.
- *
- ****************************************************************************/
-#include "config.h"
-
-    .section    .icode,"ax",@progbits
-
-    .global     memset16
-    .type       memset16,@function
-
-/* Fills a memory region with specified word value
- * Start address must be word aligned, length is in words
- * This version is optimized for speed
- *
- * arguments:
- *  (4,%sp)  - start address
- *  (8,%sp)  - data
- *  (12,%sp) - length
- *
- * return value:
- *  %d0 - start address
- *
- * register usage:
- *  %d0 - data (spread to both words when using long stores)
- *  %d1 - temporary / data (for burst transfer)
- *  %d2 - data (for burst transfer)
- *  %d3 - data (for burst transfer)
- *  %a0 - start address
- *  %a1 - current address (runs down from end to start)
- *
- * For maximum speed this routine uses both long stores and burst mode,
- * storing whole lines with movem.l. The routine fills memory from end
- * to start in order to ease returning the start address.
- */
-memset16:
-    move.l  (4,%sp),%a0     /* start address */
-    move.l  (8,%sp),%d0     /* data */
-    move.l  (12,%sp),%a1    /* length */
-    add.l   %a1,%a1
-    add.l   %a0,%a1         /* %a1 = end address */
-
-    move.l  %a0,%d1
-    addq.l  #6,%d1
-    and.l   #0xFFFFFFFC,%d1 /* %d1 = first long bound + 4 */
-    cmp.l   %d1,%a1         /* at least one aligned longword to fill? */
-    blo.b   .no_longs       /* no, jump directly to word loop */
-
-    and.l   #0xFFFF,%d0     /* start: spread data to both words */
-    move.l  %d0,%d1
-    swap    %d1
-    or.l    %d1,%d0         /* data now in both words */
-
-    move.l  %a1,%d1
-    and.l   #0xFFFFFFFC,%d1 /* %d1 = last long bound */
-    cmp.l   %d1,%a1         /* one extra word? */
-    bls.b   .end_w1         /* no: skip */
-
-    move.w  %d0,-(%a1)      /* set leading word */
-
-.end_w1:
-    moveq.l #30,%d1
-    add.l   %a0,%d1
-    and.l   #0xFFFFFFF0,%d1 /* %d1 = first line bound + 16 */
-    cmp.l   %d1,%a1         /* at least one full line to fill? */
-    blo.b   .no_lines       /* no, jump to longword loop */
-
-    mov.l   %a1,%d1
-    and.l   #0xFFFFFFF0,%d1 /* %d1 = last line bound */
-    cmp.l   %d1,%a1         /* any longwords to set? */
-    bls.b   .end_l1         /* no: skip longword loop */
-
-    /* leading longword loop: sets 0..3 longwords */
-.loop_l1:
-    move.l  %d0,-(%a1)      /* store longword */
-    cmp.l   %d1,%a1         /* runs %a1 down to last line bound */
-    bhi.b   .loop_l1
-
-.end_l1:
-    move.l  %d2,-(%sp)      /* free some registers */
-    move.l  %d3,-(%sp)
-
-    move.l  %d0,%d1         /* spread data to 4 data registers */
-    move.l  %d0,%d2
-    move.l  %d0,%d3
-    lea.l   (14,%a0),%a0    /* start address += 14, acct. for trl. data */
-    
-    /* main loop: set whole lines utilising burst mode */
-.loop_line:
-    lea.l   (-16,%a1),%a1   /* pre-decrement */
-    movem.l %d0-%d3,(%a1)   /* store line */
-    cmp.l   %a0,%a1         /* runs %a1 down to first line bound */
-    bhi.b   .loop_line
-
-    lea.l   (-14,%a0),%a0   /* correct start address */
-    move.l  (%sp)+,%d3      /* restore registers */
-    move.l  (%sp)+,%d2
-
-    move.l  %a0,%d1         /* %d1 = start address ... */
-    addq.l  #2,%d1          /* ... +2, account for possible trailing word */
-    cmp.l   %d1,%a1         /* any longwords left */
-    bhi.b   .loop_l2        /* yes: jump to longword loop */
-    bra.b   .no_longs       /* no: skip loop */
-
-.no_lines:
-    move.l  %a0,%d1         /* %d1 = start address ... */
-    addq.l  #2,%d1          /* ... +2, account for possible trailing word */
-
-    /* trailing longword loop */
-.loop_l2:
-    move.l  %d0,-(%a1)      /* store longword */
-    cmp.l   %d1,%a1         /* runs %a1 down to first long bound */
-    bhi.b   .loop_l2
-
-.no_longs:
-    cmp.l   %a0,%a1         /* any words left? */
-    bls.b   .end_w2         /* no: skip loop */
-
-    /* trailing word loop */
-.loop_w2:
-    move.w  %d0,-(%a1)      /* store word */
-    cmp.l   %a0,%a1         /* runs %a1 down to start address */
-    bhi.b   .loop_w2
-
-.end_w2:
-    move.l  %a0,%d0         /* return start address */
-    rts
-
-.end:
-    .size   memset16,.end-memset16
diff --git a/firmware/target/coldfire/strlen-coldfire.S b/firmware/target/coldfire/strlen-coldfire.S
deleted file mode 100644
index 765969da04..0000000000
--- a/firmware/target/coldfire/strlen-coldfire.S
+++ /dev/null
@@ -1,71 +0,0 @@
-/***************************************************************************
- *             __________               __   ___.
- *   Open      \______   \ ____   ____ |  | _\_ |__   _______  ___
- *   Source     |       _//  _ \_/ ___\|  |/ /| __ \ /  _ \  \/  /
- *   Jukebox    |    |   (  <_> )  \___|    < | \_\ (  <_> > <  <
- *   Firmware   |____|_  /\____/ \___  >__|_ \|___  /\____/__/\_ \
- *                     \/            \/     \/    \/            \/
- * $Id$
- *
- * Copyright (C) 2010 Nils Wallménius
- *
- * This program is free software; you can redistribute it and/or
- * modify it under the terms of the GNU General Public License
- * as published by the Free Software Foundation; either version 2
- * of the License, or (at your option) any later version.
- *
- * This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
- * KIND, either express or implied.
- *
- ****************************************************************************/
-
-/* size_t strlen(const char *str) */
-
-    .section .text,"ax",@progbits
-    .align   2
-    .globl   strlen
-    .type    strlen, @function
-
-strlen:
-    move.l   4(%sp), %a0    /* %a0 = *str */
-    move.l   %a0, %a1       /* %a1 = start address */
-    move.l   %a0, %d0
-    andi.l   #3, %d0        /* %d0 = %a0 & 3 */
-    beq.b    1f             /* already aligned */
-    jmp.l    (-2,%pc,%d0.l*4)
-    tst.b    (%a0)+
-    beq.b    .done
-    tst.b    (%a0)+
-    beq.b    .done
-    tst.b    (%a0)+
-    beq.b    .done
-
-    1:
-    move.l   (%a0)+, %d0    /* load %d0 increment %a0 */
-    /* use trick to test the whole word for null bytes */
-    move.l   %d0, %d1
-    subi.l   #0x01010101, %d1
-    not.l    %d0
-    and.l    %d1, %d0
-    andi.l   #0x80808080, %d0
-    beq.b    1b             /* if the test was false repeat */
-
- /* ok, so the last word contained a 0 byte, test individual bytes */
-    subq.l   #4, %a0
-    tst.b    (%a0)+
-    beq.b    .done
-    tst.b    (%a0)+
-    beq.b    .done
-    tst.b    (%a0)+
-    beq.b    .done
- /* last byte must be 0 so we don't need to load it, so we don't increment a0
-    so we jump past the subq instr */
-    .word    0x51fa         /* trapf.w, shadow next instr */
-
-.done:
-    subq.l   #1, %a0        /* %a0 is 1 too large due to the last increment */
-    sub.l    %a1, %a0       /* how many times did we repeat? */
-    move.l   %a0, %d0       /* return value in %d0 */
-    rts
-    .size    strlen, .-strlen
-