3 new ports: Samsung YH-820, YH-920, and YH-925. Mostly functional. Audio working on 820 & 925 (untested on the 920). No battery readings. No recording. No plugins. Keymap needs work.

git-svn-id: svn://svn.rockbox.org/rockbox/trunk@21083 a1c6a512-1295-4272-9138-f99709370657

1 files changed, 64 insertions, 0 deletions

diff --git a/firmware/target/arm/samsung/boot.lds b/firmware/target/arm/samsung/boot.lds
new file mode 100644
index 0000000000..ccc68c0916
--- /dev/null
+++ b/firmware/target/arm/samsung/boot.lds
@@ -0,0 +1,64 @@
+#include "config.h"
+
+ENTRY(start)
+OUTPUT_FORMAT(elf32-littlearm)
+OUTPUT_ARCH(arm)
+STARTUP(target/arm/crt0-pp-bl.o)
+
+#define DRAMSIZE (MEMORYSIZE * 0x100000)
+
+#define DRAMORIG 0x10000000
+#define IRAMORIG 0x40000000
+#define IRAMSIZE 0x18000
+#define FLASHORIG 0x001f0000
+#define FLASHSIZE 2M
+
+MEMORY
+{
+    DRAM : ORIGIN = DRAMORIG, LENGTH = DRAMSIZE
+    IRAM : ORIGIN = IRAMORIG, LENGTH = IRAMSIZE
+}
+
+SECTIONS
+{
+  . = IRAMORIG;
+
+  .text : {
+    *(.init.text)
+    *(.text*)
+    *(.glue_7)
+    *(.glue_7t)
+  } > IRAM
+
+  .data : {
+    *(.icode)
+    *(.irodata)
+    *(.idata)
+    *(.data*)
+    *(.ncdata*)
+    *(.rodata*)
+    _dataend = . ;
+  } > IRAM
+
+  .stack : {
+     *(.stack)
+     _stackbegin = .;
+     stackbegin = .;
+     . += 0x2000;
+     _stackend = .;
+     stackend = .;
+  } > IRAM
+
+  /* The bss section is too large for IRAM - we just move it 16MB into the
+     DRAM */
+
+  . = DRAMORIG;
+  .bss . + (16*1024*1024) : {
+     _edata = .;
+     *(.bss*);
+     *(.ibss);
+     *(COMMON)
+     *(.ncbss*);
+     _end = .;
+  } > DRAM
+}